COMMENT ⊗   VALID 00002 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002	BEGIN "SYNDMP"
C00005 ENDMK
C⊗;
BEGIN "SYNDMP"
comment display any residual XGPSYN queued files;
INTEGER CH,COUNT,BRCHAR,EOF,FLAG,REPT,I,T; STRING S;
REQUIRE "VIXHDR.SAI[VIS,HPM]" SOURCE_FILE;

REPT←1;
START_CODE SETOM T; TTCALL 6,T; END; comment getlin;
IF T≠-1∧(T LAND '4000000000)=0 THEN
   BEGIN
   START_CODE TTCALL '10,0; END;       comment RESCAN to read command line;
   S←INCHWL; WHILE LENGTH(S)>0 ∧ S≠";" DO S←S[2 TO ∞];
   S←S[2 TO ∞]; REPT←CVD(S) MAX 1;
   END;
CH←GETCHAN;

OPEN(CH,"DSK",'10,19,0,COUNT,BRCHAR,EOF);
LOOKUP(CH,"TMPHPM.UFD[1,1]",FLAG);

WHILE ¬EOF DO
DO BEGIN "FILES"
   INTEGER ARRAY RET[0:'17]; INTEGER FN,EXT; STRING SFN,SEXT;
   ARRYIN(CH,RET[0],'20); FN←RET[0]; IF FN=0 THEN DONE "FILES";
   EXT←RET[1];
   SFN←CVXSTR(FN);  WHILE SFN[∞ TO ∞]=" " DO SFN←SFN[1 TO ∞-1];
   SEXT←CVXSTR(EXT LAND '777777000000);
		   WHILE SEXT[∞ TO ∞]=" " DO SEXT←SEXT[1 TO ∞-1];
   IF LENGTH(SFN)<5 ∨ ¬EQU(SEXT,"TMP") THEN DONE "FILES";
   FOR I←1 STEP 1 UNTIL LENGTH(SFN) DO
      IF SFN[I TO I]<"0" ∨ SFN[I TO I]>"9" THEN DONE "FILES";
   I←PFLDIM("DSK:"&SFN&".TMP[TMP,HPM]");
   IF I>50000 THEN
      BEGIN
      INTEGER ARRAY PIC[0:I];
      PRINT("DSK:"&SFN&".TMP[TMP,HPM]",'15&'12);
      GETPFL("DSK:"&SFN&".TMP[TMP,HPM]",PIC[0]);
      IF VIDXGP(PIC[0],0,-36,2200,REPT) THEN
	 BEGIN INTEGER COUNT,BRCHAR,EOF,CH,FLAG;  comment delete the XGP'd file;
	 CH←GETCHAN;
	 OPEN(CH,"DSK",'10,0,1,COUNT,BRCHAR,EOF);
	 ENTER(CH,SFN&".TMP[TMP,HPM]",FLAG);
	 RENAME(CH,"",0,FLAG);
	 RELEASE(CH);
	 END;
      END;
   END "FILES" UNTIL TRUE;
END;